# gemtext2html
# convierte un archivo en gemtext a html de acuerdo a la spec
# excepción: enlaces a imagen (jpg, png, gif) se vuelven <img>
# TODO actualizar descripción
#
# importante: solo un {wikilink} (con o sin espacios) por línea
#
# modo de uso:
# awk -f gemtext2html.awk archivo.gmi > archivo.html
#
BEGIN{
sitio = "HOLO"
# para poder abrir y cerrar <ul>, <pre>, <p>:
modo_lista = 0
modo_pre = 0
modo_parrafo = 0
modo_galeria = 0
en_section = 1
bloque = 0 # para no agregar <br/> después de headers y blockquotes
print "<!DOCTYPE html PUBLIC '-//W3C//DTD XHTML 1.0 Transitional//EN' 'http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd'>"
print "<html xmlns='http://www.w3.org/1999/xhtml' lang='es-MX'>"
print "<head>"
print "<meta http-equiv='Content-Type' content='text/html; charset=utf-8' />"
print "<meta content='initial-scale=1.0, maximum-scale=1.0, user-scalable=yes' name='viewport'/>"
print "<link rel='stylesheet' href='./static/estilo.css'>"
contenido = "<main><section>"
nav = "<nav><ul>"
}
function appendContenido( t ){
contenido = contenido t "\n"
}
function appendNav( t ){
nav = nav t "\n"
}
function wikiLink( t ){
i = match( t, /{.+}/)
if ( i ){
ifinal = index(t, "}") # índice del } final
prev = substr(t, 1, i-1) # string previa al link
link = substr(t, i, ifinal-i+1) # {link}
nombre = substr(t, i+1, ifinal-i-1) # link
gsub(" ","_",nombre) # reemplaza espacios por _
post = substr(t, ifinal+1) # string posterior
return prev "<a href='./" nombre ".html'>" link "</a>" post
}
else{
return t
}
}
NR == 1{
titulo = $0
sub("#[[:blank:]]+","",titulo) #prefijo
print "<title>" sitio " — " titulo "</title>"
print "</head>"
print "<body>"
print "<header>"
print "<p><a href='./index.html'>{" sitio "}</a></p>"
print "<h1>"titulo"</h1>"
print "</header>"
bloque = 1
getline # lee la siguiente línea
}
$0 !~ /^(=>|```|#{1,3} |* |>|[[:blank:]]*$)/{ # líneas de texto (no "especiales")
if(!modo_pre){
if(!modo_parrafo){
modo_parrafo = 1
appendContenido( "<p>" )
}
else # nueva línea en el mismo párrafo
appendContenido( "<br/>" )
# busca y convierte wikiLink (máx uno por línea)
appendContenido( wikiLink($0) )
}
else{
appendContenido( $0 )
}
}
/^[[:blank:]]*$/ { # línea vacía
if( !modo_pre ) {
if( modo_lista ){ # cierra la lista
modo_lista = 0
appendContenido( "</ul>" )
}
else if( modo_parrafo ){ # cierra el párrafo
modo_parrafo = 0
appendContenido( "</p>" )
}
else if( modo_galeria ){
modo_galeria = 0
appendContenido( "</gallery>" )
}
# else
# appendContenido( "<br/>" )
if( bloque ) # si lo previo fue header o blockquote
bloque = 0;
}
else
appendContenido( $0 )
}
/^=>/{ # link
if(!modo_pre){
if( modo_lista ){ # cierra la lista
modo_lista = 0
appendContenido( "</ul>" )
}
else if( modo_parrafo ){ # cierra el párrafo
modo_parrafo = 0
appendContenido( "</p>" )
}
bloque = 1 #empieza bloque porque es <p>
# borra flecha del inicio
sub("^=>","",$0)
# ahora $1 es el path, $2 a $NF el texto
# concatena todo el texto
texto = $2
for(i=3; i<=NF; i++){
texto = texto" "$i
}
if( match($1, /^\.\//)) { # si es link local
# si el path es imagen
if( match($1, /(png|jpg|gif)$/) ){
# crea imagen <img>
if( !modo_galeria ){
appendContenido("<gallery>")
modo_galeria = 1
}
appendContenido("<img src='"$1"' alt='"texto"' loading='lazy'/>")
}
# si el path no es imagen
else{
# convierte enlace de .gmi a .html !
sub(".gmi$",".html",$1)
# crea link <a>
appendContenido("<p><a href='"$1"'>"texto"</a></p>")
}
}
else{ # link externo
appendContenido("<p><a href='"$1"' rel=external target=_blank>"texto"</a></p>")
}
}
else{
appendContenido( $0 )
}
}
/^* /{ # lista
if(!modo_pre){
if(!modo_lista){ # inicia la lista
if(modo_parrafo){
modo_parrafo = 0
appendContenido( "</p>" )
}
modo_lista = 1
appendContenido( "<ul>" )
}
sub("*[[:blank:]]+","<li>",$0)
sub("$","</li>",$0)
}
appendContenido( $0 )
}
/^```/{ # preformatted
if(modo_pre){
# cierra preformatted
modo_pre = 0
appendContenido( "</pre>" )
}
else{
if( modo_lista ){ # cierra la lista
modo_lista = 0
appendContenido( "</ul>" )
}
else if( modo_parrafo ){ # cierra el párrafo
modo_parrafo = 0
appendContenido( "</p>" )
}
# abre preformatted
modo_pre = 1
appendContenido( "<pre>" )
}
}
/^> /{ # blockquote
if(!modo_pre){
sub(">[[:blank:]]+","<blockquote>",$0)
sub("$","</blockquote>",$0)
bloque = 1
}
appendContenido( $0 )
}
/^# /{ # h1
if(!modo_pre){
sub("#[[:blank:]]+","",$0) #prefijo
sub("$","",$0) #sufijo
bloque = 1
if( !en_section ){ # si no se ha iniciado una sección antes
appendContenido( "<section>" )
en_section = 1
}
else{
appendContenido( "</section><section>" )
}
# crea header con id
appendContenido( "<h1 id='"$0"'>"$0"</h1>" )
# agrega header a navegación
appendNav( "<li><a href='#"$0"'>"$0"</a></li>" )
}
else{
appendContenido( $0 )
}
}
/^## /{ # h2
if(!modo_pre){
sub("##[[:blank:]]+","<h2>",$0)
sub("$","</h2>",$0)
bloque = 1
}
appendContenido( $0 )
}
/^### /{ # h3
if(!modo_pre){
sub("###[[:blank:]]+","<h3>",$0)
sub("$","</h3>",$0)
bloque = 1
}
appendContenido( $0 )
}
END{
# imprime y cierra nav
print nav
print "</ul></nav>"
# imprime contenido
print contenido
# cierra tags que pudieron haber quedado abiertas
if(modo_pre)
print "</pre>"
else if(modo_parrafo)
print "</p>"
else if(modo_lista)
print "</ul>"
# finaliza...
print "</section>"
print "</main>"
print "<footer>"
print "<p>página actualizada en: "
fecha = system( "date -r " FILENAME " --rfc-3339=date" )
print "</p>"
print "<p><a href='./index.html'>{" sitio "}</a></p>"
print "<a href='https://endefensadelsl.org/ppl_es.html' rel=external target=_blank>ppl: licencia de producción de pares</a></p>"
print "</footer>"
print "</body>"
print "</html>"
}